# Maintainer: clsr <clsr@clsr.net>

pkgname=dwmclock
pkgver=1.3.2
pkgrel=1
pkgdesc="Time and battery charge display for dwm"
arch=('x86_64')
url="https://git.clsr.net/util/dwmclock/about/"
license=('custom:Public Domain')
depends=('libx11')
source=("https://git.clsr.net/util/dwmclock/snapshot/dwmclock-$pkgver.tar.gz"
        config.mk)
sha256sums=('f3b9d49f151350857fbe30813f56a20b8aa570407aa1853f7cf0ec0c9b749138'
            'SKIP')

prepare() {
	cd "$pkgname-$pkgver"
	if [[ -f "$srcdir/config.mk" ]]; then
		cp -fv "$srcdir/config.mk" config.mk
	elif [[ ! -f config.mk ]]; then
		cp -v config.def.mk config.mk
	fi
}

build() {
	cd "$pkgname-$pkgver"
	make
}

package() {
	cd "$pkgname-$pkgver"
	make DESTDIR="$pkgdir/" PREFIX="/usr" install
	install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
